TCP协议是TCP/IP协议簇中的传输层中的一个协议，也是TCP/IP协议簇最为重要的协议之一。在TCP/IP协议簇中，有一个协议和TCP协议非常类似，这就是UDP协议，网络上进行基于UDP协议的数据传送时，发送方只需知道接收方的IP地址（或主机名）和端口号就可以发送UDP数据包。而接收方只需知道发送方发送数据对应的端口号，就能够接收UDP数据包了。传送数据的双方并不需要进行连接就能够实现数据通讯，这样就导致基于UDP协议的网络应用程序，在传送数据时无法保证可靠性、完整性和安全性。

　　　而TCP协议却与之相反，TCP协议是一种面向连接的，并提供可靠的、完整的、安全的数据传送的网络协议。它提供可靠字节服务的协议。在网络中通过TCP协议传送数据之前，发送方和接收方之间必须建立连接，这种连接就是所谓的"握手"。网络中TCP应用，如同日常生活中的打电话，在通话之前，首先要拨号、震铃（犹如发送方向接收方提出TCP连接申请，并等待TCP连接申请通过）。直到对方拿起电话时（发送方和接收方的TCP连接已经建立），就可以通话了（传送数据）。本文的主要内容就来介绍在Visual Basic .Net实现基于TCP协议网络数据传送的一种简单的方法。

　　一．简介本文在实现TCP协议网络应用时使用的类库：

　　.Net FrameWork SDK中提供了很多用以实现TCP协议或与之相关协议的类库，本文就选择五个比较典型，也是比较简单的类加以介绍，即：TcpListener类、TcpClient类、NetworkStream类、StreamReader类和StreamWriter类。TcpClient主要用以提出TCP连接申请。TcpListener主要用以侦听端口号，并接收远程主机的TCP连接申请。NetworkStream类是实现TCP数据传输的基础数据流，StreamReader类作用是通过操作NetworkStream，实现从网络接收数据。StreamWriter类作用是通过操作NetworkStream，实现向网络传输数据。

　　1. NetworkStream类：

　　NetworkStream类主要是提供用于网络访问的基础数据流。它主要是网络数据传输的载体，并提供同步、异步方式来访问网络数据流。虽然NetworkStream类有构造函数，但在实际情况中更多是通过TcpClient实例的GetStream方法来初始化NetworkStream实例。以下就是使用TcpClient实例的GetStream方法来初始化NetworkStream实例具体代码：

Dim tcpClient As TcpClient
Dim nsStream As NetworkStream
tcpClient = New TcpClient( "www.microsoft.com" , 8000)
'对远程主机的8000端口提出TCP连接申请
nsStream = tcpClient.GetStream ( )
'TCP连接建立后，获得网络数据传输的基础数据流

　　在下面介绍的程序示例中，就是利用NetworkStream作为传送和接收数据的载体。而操作这个载体的就是StreamWriter类和StreamReader类。表01和表02是NetworkStream类中一些常用的方法、属性及其说明。

方法 说明
BeginRead 开始异步读者基础数据流。
BeginWrite  开始异步写入基础数据流。
Close 关闭流并可选择关闭基础套接字。
EndRead  结束异步读取。
EndWrite 结束异步写入。
Flush 刷新流中的数据。
Read  从流中读取数据。
Seek 将流的当前位置设置为给定值。
SetLength 设置流的长度。
Write  将数据写入流。

表01：NetworkStream类中常用的方法及其说明

　　其中"BeginRead"、"EndRead"和"BeginWrite"、"EndWrite"是二对异步方法，起作用分别相当于"Read"和"Write"方法。

属性 说明
CanRead 获取当前流是否支持读取。
CanSeek 获取流是否支持查找。该属性总是返回 false。
CanWrite 获取当前流是否支持写入。
DataAvailable 获取是否可以在流上读取数据。
Length 流上可用数据的长度。
Position  获取或设置流中的当前位置。

表02：NetworkStream类中属性及其说明

　　2. StreamReader类：

　　StreamReader类能够实现对基础数据流的读操作，从而实现对经过基础数据流传送来的数据。表03是StreamReader类的常用的方法及其说明：

方法 说明
Close 关闭StreamReader并释放与阅读器关联的所有系统资源。
DiscardBufferedData 允许StreamReader丢弃其当前数据。
Peek 返回下一个可用的字符，但不使用它。
Read 读取输入流中的下一个字符或下一组字符。
ReadBlock  从当前流中读取最大数量的字符并从索引开始将该数据写入缓冲区。
ReadLine 从当前流中读取一行字符并将数据作为字符串返回。
ReadToEnd  从流的当前位置到末尾读取流。

表03：NetworkStream类中常用的方法及其说明

　　3. StreamWriter类：

　　StreamWriter类能够实现对基础数据流的写操作，从而实现提供基础数据流来传送数据。表04是StreamWriter类的常用方法及其说明：

方法 说明
Close  关闭当前的StreamWriter和基础流。
Flush 清理当前编写器的所有缓冲区，并使所有缓冲数据写入基础流。
Write 写入基础数据流。
WriteLine 写入重载参数指定的某些数据，后跟行结束符。

表04：StreamWriter类的常用方法及其说明

4.TcpClient 类：

　　TcpClient 类主要为TCP网络服务提供客户端连接。TcpClient是类基于Socket类构建，
它以更高的抽象程度提供TCP服务。TcpClient 提供了通过网络连接、发送和接收数据的简单方法。表05和表06分别是TcpClient类常用方法、属性及其说明。

方法 说明
Close  关闭 TCP 连接
Connect 使用指定的主机名和端口号将客户端连接到 TCP主机
GetStream  返回用于发送和接收数据的流

表05：TcpClient类常用的方法

属性 描述
LingerState 有关套接字逗留时间的信息
NoDelay 一个值，该值在发送或接收缓冲区未满时启用延迟
ReceiveBufferSize 接收缓冲区的大小
ReceiveTimeout TcpClient在启动后为接收数据而等待的时间长度
SendBufferSize  发送缓冲区的大小
SendTimeout  在您启动发送操作后TcpClient将为接收确认而等待的时间长度

表06：TcpClient类常用的属性

　　5.TcpListener 类：

　　TcpListener类的主要作用是从TCP网络客户端侦听连接，TcpListener类基于Socket 类
提供更高理念级别的TCP服务。可以使用TcpListener从TCP客户端侦听连接。像 FTP 和 HTTP 这样的应用层协议是在 TcpListener 类的基础上建立的。表7和表8分别是TcpListener类常用方法、属性及其说明：

方法 说明
AcceptSocket 接受挂起的连接请求
AcceptTcpClient 接受挂起的连接请求
Pending 确定是否有挂起的连接请求
Start 开始侦听网络请求
Stop  关闭侦听器

表7：TcpListener 类常用的方法

属性 说明
LocalEndpoint  获取当前TcpListener的基础EndPoint
Active 获取一个值，该值指示 TcpListener 是否正主动侦听客户端连接
Server 获取基础网络Socket

表8：TcpListener 类常用的属性

二．Visual Basic .Net实现基于TCP协议数据传送程序的体系结构：

　　在下面介绍的用Visual Basic .Net实现基于TCP协议的数据传送程序是由二个子程序组成的。也可以看成是服务器端程序和客户端程序，其中：服务器端程序的功能是侦听端口号，接收远程主要的TCP连接申请，并接收远程主机传送来的文字数据。另外一个子程序，也就是所谓的客户端程序，主要实现向网络的远程主机提出TCP连接申请，并在连接申请通过后，向远程主机传送文字数据。下面来详细介绍Visual Basic .Net实现TCP协议网络数据传送的服务器端程序和客户端程序的具体步骤。

　　三．服务器端程序的具体实现步骤：

　　服务器端程序的实现关键在于侦听端口号，接收远程主机的TCP连接申请，获得网络数据传输的基础数据流，并通过基础数据流接收数据。接收数据使用的是StreamReader中ReadLine方法，由于ReadLine方法是一个阻塞式的方法，所以在下面具体的实现步骤中，是接收数据是在创建的线程中完成的，具体可参阅下面实现步骤中的第十一和十二步。以下是Visual Basic .Net实现TCP协议客户端程序实现的具体步骤：

　　1. 启动Visual Studio .Net。

　　2. 选择菜单【文件】|【新建】|【项目】后，弹出【新建项目】对话框。

　　3. 将【项目类型】设置为【Visual Basic项目】。

　　4. 将【模板】设置为【Windows应用程序】。

　　5. 在【名称】文本框中输入【服务器端程序】。

　　6. 在【位置】的文本框中输入【E:/VS.NET项目】，然后单击【确定】按钮，这样在"E:/VS.NET项目"目录中就产生了名称为"服务器端程序"的文件夹，并在里面创建了名称为"服务器端程序"的项目文件。

　　7. 把Visual Studio .Net的当前窗口切换到【Form1.vb（设计）】窗口，并从【工具箱】中的【Windows窗体组件】选项卡中往Form1窗体中拖入下列组件，并执行相应的操作：

　　一个Label组件。
　　一个StatusBar组件。
　　一个ListBox组件。
　　一个Button组件，并在这个Button组件拖入Form1的设计窗体后，双击它，则系统会在Form1.vb文件分别产生这个组件的Click事件对应的处理代码。

　　8. 按照表05所示调整窗体中各组件属性的数值：

组件类型 组件名称  属性 设置结果
Form Form1  Text  服务器端程序
Form1 MaximizeBox False
Form1 FormBorderStyle FixedSingle
Button Button1 Text 启动服务
  Button1 FlatStyle Flat
Label Label1 Text 服务尚未启动
StatusBar StatusBar1 Text  无连接！

表05：【服务器端程序】项目中组件设定数值表

. 把Visual Studio .Net的当前窗口切换到Form1.vb的代码编辑窗口，并在Form1.vb文件的最前面添加下列代码，下列代码在Form1.vb中导入程序中要使用的类所在的命名空间：

Imports System.Net.Sockets
'使用到TcpListen类
Imports System.Threading
'使用到线程
Imports System.IO
'使用到StreamReader类

　　10. 在Form1.vb中创建各种可视组件的代码中添加下列代码，下列代码的作用是创建全局使用的实例和变量：

Private iPort As Integer = 8000
'定义侦听端口号
Private thThreadRead As Thread
'创建线程，用以侦听端口号，接收信息
Private tlTcpListen As TcpListener
'侦听端口号
Private blistener As Boolean = True
'设定标示位，判断侦听状态
Private nsStream As NetworkStream
'创建接收的基本数据流
Private srRead As StreamReader
'从网络基础数据流中读取数据
Private tcClient As TcpClient

　　11. 在Form1.vb中的InitializeComponent过程之后添加下列代码，下列代码的作用是定义Listen过程，此过程的作用是侦听本地机的8000端口号，接受网络主机的TCP连接申请，并接收从建立申请的远程主机发送来的文本数据：

Private Sub Listen ( )
Try
　tlTcpListen = New TcpListener ( iPort )
　'以8000端口号来初始化TcpListener实例
　tlTcpListen.Start ( )
　'开始监听
　StatusBar1.Text = "正在监听..."
　tcClient = tlTcpListen.AcceptTcpClient ( )
　'通过TCP连接请求
　nsStream = tcClient.GetStream ( )
　'获取用以发送、接收数据的网络基础数据流
　srRead = New StreamReader ( nsStream )
　'以得到的网络基础数据流来初始化StreamReader实例
　StatusBar1.Text = "已经建立TCP连接！"
　'循环侦听
　While blistener
　　Dim sMessage As String = srRead.ReadLine ( )
　　'从网络基础数据流中读取一行数据
　　If ( sMessage = "STOP" ) Then
　　　tlTcpListen.Stop ( )
　　　'关闭侦听
　　　nsStream.Close ( )
　　　srRead.Close ( )
　　　'释放资源
　　　StatusBar1.Text = "无连接！"
　　　thThreadRead.Abort ( )
　　　'中止线程
　　　Return
　　Else
　　　'判断是否为断开TCP连接控制码
　　　Dim sTime As String = DateTime.Now.ToShortTimeString ( )
　　　'获取接收数据时的时间
　　　ListBox1.Items.Add ( sTime + " " + sMessage )
　　End If
　End While
Catch ex As System.Security.SecurityException
　MessageBox.Show ( "侦听失败！" , "错误" )
End Try
End Sub

　　12. 用下列代码替换Form1.vb中的Button1的Click事件对应的处理代码，下列代码功能是用上面定义的Listen过程来初始化并启动线程，接收建立TCP连接的远程主机发送来的文本数据：

Private Sub Button1_Click ( ByVal sender As System.Object , ByVal e As System.EventArgs ) Handles Button1.Click
　thThreadRead = New Thread ( New ThreadStart ( AddressOf Listen ) )
　'以Listen过程来初始化线程实例
　thThreadRead.Start ( )
　'启动线程
　Button1.Enabled = False
　Label1.Text = "服务已经启动！"
　Label1.ForeColor = Color.Red
End Sub

13. 用下列代码替换Form1.vb中的Dispose过程，下面代码的作用是重新定义Dispose过程，在Dispose过程手动清除使用的资源，回收垃圾：

Protected Overloads Overrides Sub Dispose ( ByVal disposing As Boolean )
　Try
　　thThreadRead.Abort ( ) '中止线程
　　tlTcpListen.Stop ( ) '关闭侦听
　　tcClient.Close ( )
　　nsStream.Close ( )
　　srRead.Close ( ) '释放资源
　Catch
　End Try
　If disposing Then
　　If Not ( components Is Nothing ) Then
　　　components.Dispose ( )
　　End If
　End If
　MyBase.Dispose ( disposing )
End Sub

　　14. 至此在上述步骤都正确执行后，【服务器端程序】项目的全部工作就完成了。编译、生成可执行文件后，接着介绍客户端程序的实现步骤。

四．客户端端程序的具体实现步骤：

　　客户端端序的实现关键在于向网络中的远程主机提出TCP连接申请，并在申请通过后，得到传输数据的基础数据流，并通过对基础数据流进行写操作向远程主机传送文本数据。

由于在客户端程序中没有使用阻塞式的方法，所以程序中没有使用到线程。对远程主机提出TCP连接申请的具体实现方法请参阅以下第步；对基础数据流进行写操作，从而实现向远程主机传送文本数据的方法请参阅以下第步。下面客户端程序的具体实现步骤：

　　1. 启动Visual Studio .Net。

　　2. 选择菜单【文件】|【新建】|【项目】后，弹出【新建项目】对话框。

　　3. 将【项目类型】设置为【Visual Basic项目】。

　　4. 将【模板】设置为【Windows应用程序】。

　　5. 在【名称】文本框中输入【客户端程序】。

　　6. 在【位置】的文本框中输入【E:/VS.NET项目】，然后单击【确定】按钮，这样在"E:/VS.NET项目"目录中就产生了名称为"客户端程序"的文件夹，并在里面创建了名称为"客户端程序"的项目文件。

　　7. 把Visual Studio .Net的当前窗口切换到【Form1.vb（设计）】窗口，并从【工具箱】中的【Windows窗体组件】选项卡中往Form1窗体中拖入下列组件，并执行相应的操作：

　　二个Label组件。
　　二个TextBox组件。
　　一个StatusBar组件。
　　二个Button组件，并在这二个Button组件拖入Form1的设计窗体后，双击它们，则系统会在Form1.vb文件分别产生这二个组件的Click事件对应的处理代码。

　　8. 按照表01所示调整窗体中各组件属性的数值：

组件类型  组件名称 属性  设置结果
Form  Form1 Text 客户端程序
Form1 MaximizeBox False
Form1 FormBorderStyle FixedSingle
Button Button1 Text 连接
Button1 FlatStyle  Flat
Button2 Text 发送
Button2  FlatStyle Flat
Label Label1  Text 服务器IP地址：
Label2 Text  信息：
StatusBar  StatusBar1 Text  无连接！
TextBox TextBox1 Text ""
TextBox1  BorderStyle  FixedSingle
TextBox2  Text ""
TextBox2 BorderStyle FixedSingle

表06：【客户端程序】项目中组件设定数值表

　　9. 把Visual Studio .Net的当前窗口切换到Form1.vb的代码编辑窗口，并在Form1.vb文件的最前面添加下列代码，下列代码在Form1.vb中导入程序中要使用的类所在的命名空间：

Imports System.Net.Sockets
'使用到TcpListen类
Imports System.IO
'使用到StreamWriter类
Imports System.Net
'使用IPAddress类、IPHostEntry类等

　　10. 在Form1.vb中创建各种可视组件的代码中添加下列代码，下列代码的作用是创建全局使用的实例和变量：

Private swWriter As StreamWriter
　'用以向网络基础数据流传送数据
　Private nsStream As NetworkStream
　'创建发送数据的网络基础数据流
　Private tcpClient As TcpClient
　'通过它实现向远程主机提出TCP连接申请
　Private tcpConnect As Boolean = False
　'定义标识符，用以表示TCP连接是否建立

11. 用下列代码替换Form1.vb中的Button1的Click事件对应的处理代码，下列代码功能是向远程主机的8000端口号提出TCP连接申请，并在连接建立后，初始化基础数据流：

Private Sub Button1_Click ( ByVal sender As System.Object , ByVal e As System.EventArgs ) Handles Button1.Click
　Dim ipRemote As IPAddress
　Dim sHostName As String
　Dim tcpClient As TcpClient
　Try
　　ipRemote = IPAddress.Parse ( TextBox1.Text )
　Catch
　　MessageBox.Show ( "输入的IP地址不合法！" , "错误提示！" )
　　Return
　　'判断给定的IP地址的合法性
　End Try
　Try
　　tcpClient = New TcpClient ( TextBox1.Text , 8000 )
　　'对远程主机的8000端口提出TCP连接申请
　　nsStream = tcpClient.GetStream ( )
　　'通过申请，并获取传送数据的网络基础数据流
　　swWriter = New StreamWriter ( nsStream )
　　'使用获取的网络基础数据流来初始化StreamWriter实例
　　Button1.Enabled = False
　　Button2.Enabled = True
　　tcpConnect = True
　　StatusBar1.Text = "已经连接！"
　Catch
　　MessageBox.Show ( "无法和远程主机8000端口建立连接！" , "错误提示！" )
　　Return
　End Try
End Sub

　　12. 用下列代码替换Form1.vb中的Button2的Click事件对应的处理代码，下列代码功能是对基础数据流进行写操作，实现向远程主机传输文本数据：

Private Sub Button2_Click ( ByVal sender As System.Object , ByVal e As System.EventArgs ) Handles Button2.Click
　If ( TextBox2.Text <> "" ) Then
　　swWriter.WriteLine ( TextBox2.Text )
　　'刷新当前数据流中的数据
　　swWriter.Flush ( )
　　TextBox2.Text = ""
　Else
　　MessageBox.Show ( "发送信息不能为空！" , "错误提示！" )
　End If
End Sub

　　13. 用下列代码替换Form1.vb中的Dispose过程，下面代码的作用是重新定义Dispose过程，在过程中判断TCP连接是否仍然建立，如果建立则向远程主机传送控制码，断开连接，并手动清除使用的资源，回收垃圾：

Protected Overloads Overrides Sub Dispose ( ByVal disposing As Boolean )
　If tcpConnect Then
　　swWriter.WriteLine ( "STOP" )
　　'发送控制码
　　swWriter.Flush ( )
　　'刷新当前数据流中的数据
　　nsStream.Close ( )
　　swWriter.Close ( )
　　'清除资源 ( )
　End If
　If disposing Then
　　If Not ( components Is Nothing ) Then
　　　components.Dispose ( )
　　End If
　End If
　MyBase.Dispose ( disposing )
End Sub

　　14. 至此【客户端程序】就完成了。在正确编译项目后。就可以选择局域网中任二台计算机来测试了，一台运行客户端程序，一台运行服务器端程序。在服务器端程序运行后，单击【启动服务】按钮，启动服务后。在客户端程序的【服务器IP地址】文本框中输入网络中运行服务器端程序主机对应的IP地址后，单击【连接】按钮，就和启动服务的服务器端程序建立TCP连接，此时就可以在客户端程序的【信息】文本框中输入文本信息后，单击【发送】按钮就能够把文本信息传送到服务器端了。图03和图04分别是客户端程序和服务器端程序运行后进行通讯时的界面：

　　五．总结：

　　虽然本文用Visual Basic .Net实现一个简单的基于TCP协议的网络应用程序。但程序中使用的是NetworkStream作为载体，通过StreamWriter和StreamReader通过操作这个载体从而实现数据传输和接收。这种实现TCP协议方法虽然比较简单，但却无法回避NetworkStream作为网络传输、接收数据载体的一个致命的缺陷，那就是NetworkStream只能传输基于文本类型的数据，如果要传输基于字节的数据，使用这种方法就勉为其难了。而套接字（Socket）就能够胜任这项工作，套接字不仅能够实现各种类型数据在网络上的传输和接收，也是实现网络中其他应用协议的关键。诸位若想真正成为网络编程的高手，必须掌握Socket的使用方法。最后希望本文能够开启您编写网络应用程序之门，对您掌握更深层次网络编程有所帮助。