在CMD使用IF /?打开IF的系统帮助(自己看我就不全部列出来了),我们会发现IF有3种基本的用法!
　　　　IF [NOT] ERRORLEVEL number command
　　　　IF [NOT] string1==string2 command
　　　　IF [NOT] EXIST filename command

　　NOT 　　　　　　　　　　　把NOT理解为C/C++中的取反操作符，然后就可以理解为C/C++中的条件表达式执行
　　ERRORLEVEL number 　　如果最后运行的程序返回一个等于或大于指定数字的退出编码，指定条件为 true。
　　string1==string2  　　　　如果指定的文字字符串匹配，指定条件为 true，批处理中只有==没有!=，可以用NOT 条件表达式替代。
　　EXIST filename    　　　　 如果指定的文件名存在，指定条件为 true。
　　command           　　　　  如果符合条件，指定要执行的命令。如果指定的条件为 FALSE，命令后可跟一个执行 ELSE关键字后的命令的 ELSE 命令。

ELSE 子句必须出现在同一行上的 IF 之后。例如:

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set file="C:\abc.bat"
if exist %file% (　　　　　　　　::注意这里else后的空格
　　echo file is exists
)else ( 　　　　　　　　　　 　　 ::注意这里else要和if的子句在同一行，并且else后要有空格
　　echo file is not exists
)

pause

第一种用法：IF [NOT] ERRORLEVEL number command
　　这个用法的基本做用是判断上一条命令执行结果的代码,以决定下一个步骤.一般上一条命令的执行结果代码只有两结果,"成功"用0表示  "失败"用1表示.
举例:

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

copy C:\abc.bat E:\
if %ERRORLEVEl% == 0 (
    echo operation succ %ERRORLEVEl%
)else (
    echo operation fail %ERRORLEVEl%
)
pause

 @echo off
 Setlocal enabledelayedexpansion
 ::CODER BY dsw POWERD BY iBAT

 set /p var=随便输入一个命令
 %var%

 echo errorlevel is %ERRORLEVEL%

 if NOT %ERRORLEVEL% == 0 (
 　　echo !var!执行失败
 ) else (
　　echo !var!执行成功
 )

 pause

　　%ERRORLEVEL% 这是个系统变量,返回上条命令的执行结果代码! "成功"用0表示  "失败"用1表示.一般上一条命令的执行结果代码只有两结果,当然有的操作还有其他参数,这只是一般的情况。实际上，errorlevel返回值可以在0~255之间，比如，xcopy默认的errorlevel值就有5个，分别表示5种执行状态：

如下所示：
　　0 文件复制没有错误。
　　1 if errorlevel 2 echo。
　　2 用户按 CTRL+C 终止了 xcopy。
　　4 出现了初始化错误。没有足够的内存或磁盘空间，或命令行上输入了无效的驱动器名称或语法。
　　5 出现了磁盘写入错误。

要判断上面xcopy命令的5种退出情况，应写如下判断成才能正确执行：
　　if errorlevel 5 echo出现了磁盘写入错误
　　if errorlevel 4 echo出现了初始化错误
　　if errorlevel 2 echo用户按 CTRL+C 终止了 xcopy
　　if errorlevel 1 echo if errorlevel 2 echo
　　if errorlevel 0 echo文件复制没有错误。

再举几个例子

这个是根据你输入的命令,自动判断是成功还是失败了!

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set /p var=随便输入一个命令
%var%

::等价于if %ERRORLEVEL% == 0 (echo !var!执行成功了) ELSE (echo !var!执行失败了!)
if %ERRORLEVEL% == 0 (
    echo !var!执行成功
) else (
    echo !var!执行失败
)

pause

这里介绍的两种简写对IF的三种语法都可以套用,不单单是在IF [NOT] ERRORLEVEL number command这种法上才能用

第二种用法：IF [NOT] string1==string2 command

这个呢就是用来比较变量或者字符的值是不是相等的.

例子

 @echo off
 Setlocal enabledelayedexpansion
 ::CODER BY dsw POWERD BY iBAT

 set /p var1="请输入一个字符串："
 set /p var2="请输入一个字符串："

 if %var1% == %var2% ( echo var1 eque var2) else (echo var1 not eque var2)
 if NOT %var1% == %var2% ( echo var1 not eque var2) else (echo var1 eque var2)

 pause

　　上面这个例子可以判断你输入的值是不是相等,但是你如果输入相同的字符,但是如果其中一个后面打了一个空格,这个例子还是会认为相等,如何让有空格的输入不相等呢?我们在比较字符上加个双引号就可以了.

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set /p var1="请输入一个字符串："
set /p var2="请输入一个字符串：(加个空格试试)"

if "%var1%" == "%var2%" ( echo var1 eque var2) else (echo var1 not eque var2)
if NOT "%var1%" == "%var2%" ( echo var1 not eque var2) else (echo var1 eque var2)

pause

第三种用法：IF [NOT] EXIST filename command

这个就是判断某个文件或者文件夹是否存在的语法

例子

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set file="C:\abc.bat"
if exist %file% (            ::注意这里else后的空格
    echo file is exists
)else (                      ::注意这里else要和if在同一行，并且else后要有空格
    echo file is not exists
)

判断的文件路径加引号是为了防止路径有空格,如果路径有空格加个双引号就不会出现判断出错了!

第四种用法：IF增强的用法

  IF [/I] string1 compare-op string2 command #参数/I表示不区分大小写
  IF CMDEXTVERSION number command
  IF DEFINED variable command   　　　　　　 #判断变量是否存在，很有用

　　CMDEXTVERSION 条件的作用跟 ERRORLEVEL 的一样，除了它是在跟与命令扩展名有关联的内部版本号比较。第一个版本是 1。每次对命令扩展名有相当大的增强时，版本号会增加一个。命令扩展名被停用时，CMDEXTVERSION 条件不是真的。

如果已定义环境变量，DEFINED 条件的作用跟 EXISTS 的一样，下面两条命令效果一样。
　　IF DEFINED variable command
　　IF NOT "variable"=="" command

用“set variable=”命令使变量variable变成未定义，即空值，一句话，变量值为空，则为未定义；变量值不为空，则为已定义。
用语句IF DEFINED variable command判断变量是否存在时，请注意variable为不使用引导符号%的变量名，不能用写为%variable%，否则出错。

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

  set a=10
  if DEFINED a (echo l hava define) else (echo l don't define)
  set a=
  if DEFINED a (echo l hava define) else (echo l don't define)

pause

输出：

  l hava define
  l don't define

最后面还有一些用来判断数字的符号:
    EQU - 等于
    NEQ - 不等于
    LSS - 小于
    LEQ - 小于或等于
    GTR - 大于
    GEQ - 大于或等于

我就举一个例子,大家都懂数学...不讲多了

@echo off
Setlocal enabledelayedexpansion
::CODER BY dsw POWERD BY iBAT

set /p var=请输入一个数字:

if %var% LEQ  4 (echo 我小于等于4) ELSE echo 我不小于等于4

pause

出处：https://www.cnblogs.com/DswCnblog/p/5435231.html