ALTER TRIGGER [dbo].[trDeptInsert]
    ON [dbo].[tbDept]
    AFTER INSERT
AS
SET NOCOUNT ON
--连接inserted表得到新增的数据
--连接tbDept表取得上级节点路径，如果是顶层，就没有上级节点，所以需要LEFT JOIN
--如果是顶层，全路径就是节点名称，否则，就是上级节点全路径+当前节点名称
UPDATE A
SET Path = CASE WHEN A.ParentID = 0 THEN A.Title ELSE B.Path + ' > ' + A.Title END
FROM tbDept A INNER JOIN inserted I ON A.ID = I.ID LEFT JOIN tbDept B ON A.ParentID = B.ID

ALTER TRIGGER [dbo].[trDeptUpdate]
    ON [dbo].[tbDept]
    AFTER UPDATE
AS
SET NOCOUNT ON;
--递归查出修改了的节点以及他们的所有后代节点
--连接inserted和deleted表，并使用I.ParentID <> D.ParentID OR I.Title <> D.Title判断是否修改了名称和所属父节点
WITH temp AS (
    SELECT A.ID FROM tbDept A INNER JOIN inserted I ON A.ID = I.ID INNER JOIN deleted D ON I.ID = D.ID
    WHERE I.ParentID <> D.ParentID OR I.Title <> D.Title
    UNION ALL
    SELECT tbDept.ID FROM temp INNER JOIN tbDept ON temp.ID = tbDept.ParentID
)
--CTE数据只能使用一次，所以需要写入临时表，同时增加行号，以便遍历
SELECT ID, RowID = ROW_NUMBER() OVER(ORDER BY ID) INTO #TEMP FROM temp
--遍历上面得到的所有节点ID
DECLARE @RowCount int = (SELECT COUNT(*) FROM #TEMP), @RowID int = 1    --行数，行号
WHILE @RowCount >= @RowID
BEGIN
    DECLARE @ID int
    SELECT @ID = ID FROM #TEMP WHERE RowID = @RowID;
    --递归得到当前节点及其所有父节点名称
    WITH temp AS (
        SELECT Title, ParentID, Level = 0 FROM tbDept WHERE ID = @ID
        UNION ALL
        SELECT A.Title, A.ParentID, Level - 1 FROM tbDept A INNER JOIN temp ON A.ID = temp.ParentID
    )
    --使用FOR XML PATH拼接出节点全路径
    --使用STUFF函数去掉前面多余的连接符号
    --注意使用TYPE和.value('.','NVARCHAR(MAX)')，否则尖括号会被转义，并且value只能小写
    UPDATE tbDept
    SET Path = STUFF((SELECT ' > '+Title FROM temp ORDER BY Level FOR XML PATH(''),TYPE).value('.','NVARCHAR(MAX)'),1,3,'')
    WHERE ID = @ID
    SET @RowID = @RowID + 1
END